AXForum  
Вернуться   AXForum > Блоги > Заметки по Dynamics Ax от Poleax
NAV
Забыли пароль?
Зарегистрироваться Правила Справка Пользователи Сообщения за день Поиск Все разделы прочитаны

Рейтинг: 5.00. Голосов: 2.

Массовое развертывание клиентов Dynamics Ax 2009

Запись от Poleax размещена 07.04.2010 в 14:49
Обновил(-а) Poleax 07.04.2010 в 17:21

Массовое развертывание клиентов Dynamics Ax 2009 (Mass deployment of clients)

Появилась идея одним махом установить клиента Dynamics Ax 2009.

Читаем
Microsoft Dynamics AX 2009 Installation Guide Mass deployment of clients - 53 стр.
или
Руководство по установке Microsoft Dynamics AX 2009 Массовое развертывание клиентов - 40 стр.

В инете есть AX 2009 SP1 Client Silent Install
В скрипте указан Hotfix 963056, но он есть в Rollup 1. Rollup 1 включен в Rollup 4


Мне требовался клиент:
  • Dynamics Ax 2009
  • Dynamics Ax 2009 SP1
  • Dynamics Ax 2009 SP1 Rollup 4
  • Microsoft .NET Framework 3.5 Service pack 1 (Full Package)

Написал первую версию скрипта на основе AX 2009 SP1 Client Silent Install.
Файл AxInstallClient.cmd в архиве AxInstallClientFull.rar:
Код:
@Echo Installing Dynamicx Ax 2009 std
"\\srv-axp-tst-01\Ax 2009 ISO\Setup.exe" HideUI=1 AcceptLicenseTerms=1 InstallClientUI=1 ConfigurePrerequisites=1 ClientAosServer=DynamicsAx2009@srv-axp-tst-01:2712 ClientLanguage=ru ClientConfig=1 ClientHelpLanguages=ru;en-us 

@Echo Installing Dynamicx Ax 2009 sp1

"\\srv-axp-tst-01\SP1\axupdate.exe" HideUI=1 AcceptLicenseTerms=1 InstallComponents=1

@Echo Installing Dynamicx Ax 2009 Rollup 4
"\\srv-axp-tst-01\RU4\axupdate.exe" HideUI=1 AcceptLicenseTerms=1 InstallComponents=1
rem pause
Вторая версия включает Microsoft .NET Framework 3.5 Service pack 1.
Файл AxInstallClientFull.cmd в архиве AxInstallClientFull.rar
Код:
@ECHO OFF
@ECHO Validating Install Package
@if exist "C:\Program Files\Microsoft Dynamics AX\50\Client\Log\SP1RU4UpdateLog.txt" goto INSTALLED
@if exist "C:\Program Files\Microsoft Dynamics AX\50\Client\Log\SP1UpdateLog.txt" goto INSTALLRU4
@if exist "C:\Program Files\Microsoft Dynamics AX\50\Client\Bin\ax32.exe" goto INSTALLSP1

@if exist "C:\WINDOWS\Microsoft.NET\Framework\v3.5\vbc.exe" goto INSTALLAX

:NOTNETINSTALLED
@ECHO Installing .NET Framework 3.5 SP1
@START/w "\\srv-axp-tst-01\Ax 2009 ISO\_NET\Microsoft .NET Framework 3.5 Service pack 1 (Full Package).exe" /q /norestart
:LOOPTRANS
if not exist "C:\WINDOWS\Microsoft.NET\Framework\v3.5\vbc.exe" goto LOOPTRANS

:INSTALLAX
@ECHO Starting installation Dynamics Ax 2009 
@START/w \\srv-axp-tst-01\"Ax 2009 ISO"\Setup.exe LogDir="C:\Program Files\Microsoft Dynamics AX\50\Client\Log\AX2009Log.txt" SETUPLANGUAGE="ru" ConfigurePrerequisites="1" RUNMODE="JustClient" HIDEUI="1" ACCEPTLICENSETERMS="1" CLIENTLANGUAGE="ru" CLIENTHELPLANGUAGES="ru" CLIENTAOSSERVER="DynamicsAx2009@srv-axp-tst-01:2712"
:LOOPTRANS2
@if not exist "c:\Program Files\Microsoft Dynamics AX\50\Client\Bin\Ax32.exe" goto LOOPTRANS2
@GOTO INSTALLSP1

:INSTALLSP1
@ECHO Starting installation of Dynamics Ax 2009 SP1
@START/w \\srv-axp-tst-01\SP1\axupdate.exe LogDir="C:\Program Files\Microsoft Dynamics AX\50\Client\Log\SP1UpdateLog.txt" HideUI=1 AcceptLicenseTerms=1 InstallComponents=1
:LOOPTRANS3
@if not exist "C:\Program Files\Microsoft Dynamics AX\50\Client\Log\SP1UpdateLog.txt" goto LOOPTRANS3

:INSTALLRU4
@ECHO Starting installation of Dynamics Ax 2009 SP1 Rollup 4
@START/w \\srv-axp-tst-01\RU4\axupdate.exe LogDir="C:\Program Files\Microsoft Dynamics AX\50\Client\Log\SP1RU4UpdateLog.txt" HideUI=1 AcceptLicenseTerms=1 InstallComponents=1
:LOOPTRANS4
@if not exist "C:\Program Files\Microsoft Dynamics AX\50\Client\Log\SP1RU4UpdateLog.txt" goto LOOPTRANS4
@GOTO COMPLETE

:COMPLETE
@ECHO Installation complete.
@GOTO END

:INSTALLED
@ECHO SP1 Client Already Installed
@GOTO END

:END
@ECHO The end :) 
@PAUSE
Теперь устанавливать клиента стало проще

Только вот размер \Program Files\Microsoft Dynamics AX\ ~ 505Mb


В Руководство по установке Microsoft Dynamics AX 2009
Массовое развертывание клиентов - 41 стр.

Написано:
Цитата:
3. Дополнительно. Чтобы установить клиенты, не устанавливая служебную программу настройки клиента Microsoft Dynamics AX, нужно задать для параметра ClientConfig нулевое значение.
4. Дополнительно. Чтобы настроить клиенты на использование общего файла конфигурации, нужно указать для параметра ClientConfigFile путь к этому файлу в общем каталоге. ClientConfigFile="X:\<name of configuration file>.axc"
Не стал это использовать, просто четко прописал
PHP код:
CLIENTAOSSERVER="DynamicsAx2009@srv-axp-tst-01:2712" CLIENTLANGUAGE="ru" CLIENTHELPLANGUAGES="ru" 
Server: srv-axp-tst-01
AOS: DynamicsAx2009
Port(default):2712

Запускаеть клиент можно сразу после выполнения скрипта


осталось разобраться с пунктом Microsoft Systems Management Server стр. 40:
Цитата:
Воспользуйтесь средством массового развертывания, таким как групповая политика или сервер Microsoft Systems Management Server, чтобы запустить командный файл из сценария входа.
Дополнительные сведения об использовании групповой политики для развертывания программного обеспечения можно найти по следующей ссылке: http://go.microsoft.com/fwlink/?LinkId=92736.
Дополнительные сведения об использовании сервера Microsoft Systems Management Server для развертывания программного обеспечения см. по следующей ссылке: http://go.microsoft.com/fwlink/?LinkId=115327.
Размещено в Без категории
Просмотров 27336 Комментарии 4
Всего комментариев 4

Комментарии

  1. Старый комментарий
    Запись от Poleax размещена 09.04.2010 в 16:38 Poleax is offline
  2. Старый комментарий
    Аватар для Poleax
    У меня на некоторых машинах прослеживалась ошибка запуска клиента. В реестре, почему то не прописывались полные пути.
    Пришлось исправлять файлом реестра.
    Код:
    Windows Registry Editor Version 5.00
    
    [HKEY_CURRENT_USER\Software\Microsoft\Dynamics\5.0\Configuration\Original (installed configuration)]
    "_clientadname"=""
    "_clientmode"=dword:00000000
    "allowunauth"=dword:00000000
    "aol"="usr"
    "aolcode"=""
    "aos"=""
    "aos2"="DynamicsAx2009@srv-axp-tst-01:2712"
    "aosencryption"="1"
    "applexclusive"=dword:00000000
    "application"=""
    "applshare"=dword:00000001
    "bindir"="C:\\Program Files\\Microsoft Dynamics AX\\50\\Client\\Bin"
    "broadcast"=""
    "cachesynctime"=""
    "client"="thin"
    "company"=""
    "compwd"=""
    "connectionidletimeout"=""
    "createdsn"=""
    "database"="AXDB"
    "datadir"="C:\\Program Files\\Microsoft Dynamics AX\\50\\Client\\Data"
    "dbcli"="odbc"
    "dbunicodeenabled"="1"
    "directory"="C:\\Program Files\\Microsoft Dynamics AX\\50\\Client"
    "dsn"=""
    "exposeserverprinters"=dword:00000000
    "extracmdline"=""
    "fetchahead"=""
    "hascompwd"=dword:00000000
    "hasocipwd"=dword:00000000
    "hasserveridletimeout"=dword:00000000
    "hassqlpwd"=dword:00000000
    "haswarnings"=dword:00000000
    "hint"=""
    "ignoredatasourceindex"="0"
    "installationlanguage"="ru"
    "localappldoc"=dword:00000000
    "localsysdoc"=dword:00000000
    "log"=""
    "logdir"="C:\\Documents and Settings\\All Users\\Application Data\\Microsoft\\Dynamics Ax\\Log\\"
    "native"=dword:00000000
    "newconnectionretrycount"=""
    "newconnectionretrydelayms"=""
    "ociconnectservice"="1"
    "ocidbid"=""
    "ocihost"=""
    "ociservice"=""
    "ocitcpipport"="1521"
    "opencursors"=""
    "port"=""
    "preloadthresholdmsec"=""
    "preloadthresholdrecords"=""
    "querytimelimit"=""
    "retry"=""
    "serveridletimeout"=""
    "servermask"=""
    "sql"=dword:00000001
    "sqlbuffer"=""
    "sqlcomplexliterals"="1"
    "sqlformliterals"="1"
    "sqloraclefirstrowsfix"="0"
    "sqlpwd"=""
    "sqltrace"="0"
    "sqluser"=""
    "startupcmd"=""
    "startupmsg"=""
    "user"=""
    "useserverprinters"=dword:00000000
    "warnings"=""
    "xppdebug"="0"
    "traceeventsenabled"="1"
    "tracexppmethodcalldepth"="3"
    "tracemaxfilesize"="10000"
    "tracebuffersize"="1024"
    "tracemaxbuffers"="120"
    "traceminbuffers"="30"
    "traceallowclient"=dword:00000000
    "tracestart"=dword:00000000
    
    [HKEY_CURRENT_USER\Software\Microsoft\Dynamics\5.0\Configuration\Original (installed configuration)\SetupProperties]
    "INSTALLFOLDER32"=""
    "CLIENTAOSSERVER"="DynamicsAx2009@srv-axp-tst-01:2712"
    "INSTALLLANGUAGE"="ru"
    "AOS2"="DynamicsAx2009@srv-axp-tst-01:2712"
    "CLIENTCONFIGFILE"=""
    При ручной установке Ax 2009 + Sp1 + RU4 в реестре все нормально.
    Почему команды установки аксапты не корректно прописали в реестре пути, не знаю
    Запись от Poleax размещена 04.06.2010 в 13:18 Poleax is offline
  3. Старый комментарий
    Аватар для Poleax
    проблема решена Проблема: Массовое развертывание клиентов Dynamics Ax 2009


    К примеру по ссылке Dynamics AX Sustained Engineering: Dynamics AX 2009 Rollup 6 has been released to Partner Source and Customer Source

    Есть выбор на загрузку Dynamics Ax 2009 SP1 Rollup 6:
    • Microsoft Dynamics AX 2009 All (Global) x86 sp1 KB2405516
    • Microsoft Dynamics AX 2009 All (Global) x86 sp1 KB2405516_BinaryOnly

    Для команды @START/w \\SERVER\RU6\axupdate.exe LogDir="C:\Program Files\Microsoft Dynamics AX\50\Client\Log\SP1RU6UpdateLog.txt" HideUI=1 AcceptLicenseTerms=1 InstallComponents=1 вполне подойдет пакет KB2405516_BinaryOnly. Место занимает при распаковке в 14 раз меньше чем KB2405516. Прекрасно обновляет клиентов и AOS (проверено).
    Отличие KB2405516 от KB2405516_BinaryOnly в наличии обновлений для Application

    P.S. Думаю, что блок команд с @ECHO Installing .NET Framework 3.5 SP1 не особо нужен.
    Так как ниже есть команда с ключем @START/w \\SERVER\"Ax_2009_ISO"\Setup.exe ........ ConfigurePrerequisites=1 Он ставит все не достающее.

    Код:
    Setup.exe LogDir="C:\Program Files\Microsoft Dynamics AX\50\Client\Log\AX2009Log.txt" InstallPath="%ProgramFiles%\Microsoft Dynamics AX\50" InstallPath32Bit="%ProgramFiles%\Microsoft Dynamics AX\50" HideUI=1 AcceptLicenseTerms=1 InstallClientUI=1 ClientAosServer="DynamicsAx2009@SrvAOS" ClientLanguage=ru ClientHelpLanguages=ru
    т.е.
    Код:
    @ECHO OFF
    
    @ECHO Validating Install Package
    @if exist "%ProgramFiles%\Microsoft Dynamics AX\50\Client\Log\SP1RU6UpdateLog.txt" goto INSTALLED
    @if exist "%ProgramFiles%\Microsoft Dynamics AX\50\Client\Log\SP1UpdateLog.txt" goto INSTALLRollup
    @if exist "%ProgramFiles%\Microsoft Dynamics AX\50\Client\Bin\ax32.exe" goto INSTALLSP1
    
    @if exist "%SystemRoot%\Microsoft.NET\Framework\v3.5\vbc.exe" goto INSTALLAX
    @if exist "C:\WINDOWS\Microsoft.NET\Framework\v3.5\vbc.exe" goto INSTALLAX
    
    :NOTNETINSTALLED
    @ECHO Installing .NET Framework 3.5 SP1
    @START/w "\\SERVER\Ax_2009_ISO\_NET\Microsoft .NET Framework 3.5 Service pack 1 (Full Package).exe" /q /norestart
    :LOOPTRANS
    if not exist "C:\WINDOWS\Microsoft.NET\Framework\v3.5\vbc.exe" goto LOOPTRANS
    
    :INSTALLAX
    @ECHO Starting installation Dynamics Ax 2009 
    @START/w \\SERVER\"Ax_2009_ISO"\Setup.exe LogDir="C:\Program Files\Microsoft Dynamics AX\50\Client\Log\AX2009Log.txt" InstallPath="%ProgramFiles%\Microsoft Dynamics AX\50" InstallPath32Bit="%ProgramFiles%\Microsoft Dynamics AX\50" HideUI=1 AcceptLicenseTerms=1 InstallClientUI=1 ClientAosServer="DynamicsAx2009@Srv-axp-app-01" ClientLanguage=ru ClientHelpLanguages=ru  ConfigurePrerequisites=1
    
    REM  clientConfigFile="\\SERVER\Ax_2009_ISO\Ax2009.axc"
    :LOOPTRANS2
    @if not exist "c:\Program Files\Microsoft Dynamics AX\50\Client\Bin\Ax32.exe" goto LOOPTRANS2
    @GOTO INSTALLSP1
    
    :INSTALLSP1
    @ECHO Starting installation of Dynamics Ax 2009 SP1
    @START/w \\SERVER\SP1\axupdate.exe LogDir="C:\Program Files\Microsoft Dynamics AX\50\Client\Log\SP1UpdateLog.txt" HideUI=1 AcceptLicenseTerms=1 InstallComponents=1
    :LOOPTRANS3
    @if not exist "C:\Program Files\Microsoft Dynamics AX\50\Client\Log\SP1UpdateLog.txt" goto LOOPTRANS3
    
    :INSTALLRollup
    @ECHO Starting installation of Dynamics Ax 2009 SP1 Rollup 6
    @START/w \\SERVER\RU6\axupdate.exe LogDir="C:\Program Files\Microsoft Dynamics AX\50\Client\Log\SP1RU6UpdateLog.txt" HideUI=1 AcceptLicenseTerms=1 InstallComponents=1
    :LOOPTRANS4
    @if not exist "C:\Program Files\Microsoft Dynamics AX\50\Client\Log\SP1RU6UpdateLog.txt" goto LOOPTRANS4
    @GOTO COMPLETE
    
    :COMPLETE
    @ECHO Installation complete.
    @GOTO END
    
    :INSTALLED
    @ECHO SP1 Client Already Installed
    @GOTO END
    
    :END
    @ECHO The end :) 
    @PAUSE
    Запись от Poleax размещена 09.11.2010 в 11:39 Poleax is offline
    Обновил(-а) Poleax 26.11.2010 в 17:06
  4. Старый комментарий
    Аватар для Poleax
    Немного переписанный скрипт для SMS Server установка\обновление Dynamics Ax 2009 Sp1 Rollup7
    Код:
    @ECHO OFF
    
    set Distr_Ax=\\srv-fs-01\Deploy$\"Microsoft Dymanics Axapta"\
    set PATH_dotNET="%SystemRoot%\Microsoft.NET\Framework\v3.5\vbc.exe"
    set PATH_Rollup="%ProgramFiles%\Microsoft Dynamics AX\50\Client\Log\SP1RU7UpdateLog.txt"
    set PATH_SP="%ProgramFiles%\Microsoft Dynamics AX\50\Client\Log\SP1UpdateLog.txt"
    set PATH_Ax="%ProgramFiles%\Microsoft Dynamics AX\50\Client\Bin\ax32.exe"
    
    @ECHO Disk Mapping
    @net use m: \\dc2\NETLOGON\scripts
    
    
    @ECHO Validating Install Package
    @if exist %PATH_Rollup% goto INSTALLED
    @if exist %PATH_SP% goto INSTALLRollup
    @if exist %PATH_Ax% goto INSTALLSP1
    
    @if exist %PATH_dotNET% goto INSTALLAX
    
    :NOTNETINSTALLED
    @ECHO Installing .NET Framework 3.5 SP1
    @START/w %Distr_Ax%"Ax_2009_ISO\_NET\Microsoft .NET Framework 3.5 Service pack 1.exe" /q /norestart
    
    :LOOPTRANS
    if not exist %PATH_dotNET% goto LOOPTRANS
    
    :INSTALLAX
    @ECHO Starting installation Dynamics Ax 2009 
    @START/w %Distr_Ax%"Ax_2009_ISO\Setup.exe" LogDir="%ProgramFiles%\Microsoft Dynamics AX\50\Client\Log\AX2009Log.txt" InstallPath="%ProgramFiles%\Microsoft Dynamics AX\50" InstallPath32Bit="%ProgramFiles%\Microsoft Dynamics AX\50" HideUI=1 AcceptLicenseTerms=1 InstallClientUI=1 ClientAosServer="DynamicsAx2009@Srv-axp-app-01" ClientLanguage=ru ClientHelpLanguages=ru ConfigurePrerequisites=1
    
    :LOOPTRANS2
    @if not exist %PATH_Ax% goto LOOPTRANS2
    @GOTO INSTALLSP1
    
    :INSTALLSP1
    @ECHO Starting installation of Dynamics Ax 2009 SP1
    @START/w %Distr_Ax%"SP1\axupdate.exe" LogDir=%PATH_SP% HideUI=1 AcceptLicenseTerms=1 InstallComponents=1
    
    :LOOPTRANS3
    @if not exist %PATH_SP% goto LOOPTRANS3
    
    :INSTALLRollup
    @ECHO Starting installation of Dynamics Ax 2009 SP1 Rollup 7
    @START/w %Distr_Ax%"RU7\axupdate.exe" LogDir=%PATH_Rollup% HideUI=1 AcceptLicenseTerms=1 InstallComponents=1
    
    :LOOPTRANS4
    @if not exist %PATH_Rollup% goto LOOPTRANS4
    rem @GOTO COMPLETE
    
    :COMPLETE
    @ECHO Installation complete.
    @GOTO END
    
    :INSTALLED
    @ECHO SP1 Client Already Installed
    @GOTO END
    
    :END
    
    @ECHO Delete Disk Mapping
    @net use m: /delete /y
    
    @ECHO The end :)
    set PATH_Rollup=
    set PATH_SP=
    set PATH_Ax=
    set PATH_dotNET=
    set Distr_Ax=
    Запись от Poleax размещена 30.05.2011 в 13:37 Poleax is offline
    Обновил(-а) Poleax 30.05.2011 в 13:39
 


Рейтинг@Mail.ru
Часовой пояс GMT +3, время: 10:38.
Powered by vBulletin® v3.8.5. Перевод: zCarot
Контактная информация, Реклама.